wl-vapi-gen: init at 1.1.0

pkgs/by-name/wl/wl-vapi-gen/package.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  meson,
+  ninja,
+  python3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wl-vapi-gen";
+  version = "1.1.0";
+
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "kotontrion";
+    repo = "wl-vapi-gen";
+    tag = finalAttrs.version;
+    hash = "sha256-Wi6zDrabUjIXJuxRJ9oHYfKF1ULkim/5kHGb+pl0oc4=";
+  };
+
+  postPatch = ''
+    patchShebangs wl-vapi-gen.py
+  '';
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    python3
+  ];
+
+  meta = {
+    description = "Generate vala bindings for wayland protocols";
+    homepage = "https://codeberg.org/kotontrion/wl-vapi-gen";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.PerchunPak ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/development/libraries/astal/modules/river.nix

@@ -1,11 +1,17 @@
-{ buildAstalModule, json-glib }:
+{
+  buildAstalModule,
+  json-glib,
+  wl,
+  wl-vapi-gen,
+}:
 buildAstalModule {
   name = "river";
-  buildInputs = [ json-glib ];
+  nativeBuildInputs = [ wl-vapi-gen ];
+  buildInputs = [
+    json-glib
+    wl
+  ];
   meta.description = "Astal module for River using IPC";
-  # needs https://codeberg.org/kotontrion/wl-vapi-gen,
-  # which has 11 commits and needs to be packaged
-  meta.broken = true;
 
   postUnpack = ''
     rm -rf $sourceRoot/subprojects

pkgs/development/libraries/astal/modules/wl.nix

@@ -1,9 +1,6 @@
-{ buildAstalModule }:
+{ buildAstalModule, wl-vapi-gen }:
 buildAstalModule {
   name = "wl";
-  buildInputs = [ ];
+  nativeBuildInputs = [ wl-vapi-gen ];
   meta.description = "Central wayland connection manager";
-  # needs https://codeberg.org/kotontrion/wl-vapi-gen,
-  # which has 11 commits and needs to be packaged
-  meta.broken = true;
 }