c4patino/nixpkgs
1
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2026-07-06 17:13:24 -05:00
Code Issues Projects Releases Packages Wiki Activity

nixos/comma: init (#426405)

Browse source
This commit is contained in:
Artturin 2026-07-03 17:32:00 +00:00 • committed by GitHub
commit 4f0be9c89e
No known key found for this signature in database
GPG key ID: B5690EEEBB952194
2 changed files with 53 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

1
nixos/modules/module-list.nix
View file

@ -193,6 +193,7 @@
./programs/chrysalis.nix
./programs/clash-verge.nix
./programs/cnping.nix
./programs/comma.nix
./programs/command-not-found/command-not-found.nix
./programs/coolercontrol.nix
./programs/corefreq.nix

52
nixos/modules/programs/comma.nix Normal file
View file

@ -0,0 +1,52 @@
{
lib,
config,
pkgs,
...
}:
let
cfg = config.programs.comma;
in
{
options.programs.comma = {
enable = lib.mkEnableOption "comma";
package = lib.mkPackageOption pkgs "comma" { };
enableBashIntegration = lib.mkEnableOption "comma command-not-found handler for bash" // {
default = true;
};
enableZshIntegration = lib.mkEnableOption "comma command-not-found handler for zsh" // {
default = true;
};
enableFishIntegration = lib.mkEnableOption "comma command-not-found handler for fish" // {
default = true;
};
};
config = lib.mkIf cfg.enable {
environment.systemPackages = [ cfg.package ];
programs = {
bash.interactiveShellInit = lib.mkIf cfg.enableBashIntegration ''
source ${cfg.package}/share/comma/command-not-found.sh
'';
zsh.interactiveShellInit = lib.mkIf cfg.enableZshIntegration ''
source ${cfg.package}/share/comma/command-not-found.sh
'';
fish.interactiveShellInit = ''
source ${cfg.package}/share/comma/command-not-found.fish
'';
# Disable *other* command-not-found handlers
command-not-found.enable = lib.mkIf (
cfg.enableBashIntegration || cfg.enableZshIntegration || cfg.enableFishIntegration
) (lib.mkDefault false);
nix-index = {
enableBashIntegration = lib.mkIf (cfg.enableBashIntegration) (lib.mkDefault false);
enableZshIntegration = lib.mkIf (cfg.enableZshIntegration) (lib.mkDefault false);
enableFishIntegration = lib.mkIf (cfg.enableFishIntegration) (lib.mkDefault false);
};
};
};
meta.maintainers = with lib.maintainers; [ pandapip1 ];
}