From d00eb26967dfa68e63cd0d901e6a50e9ce0ea8b6 Mon Sep 17 00:00:00 2001
From: Martin Weinelt <hexa@darmstadt.ccc.de>
Date: Tue, 12 May 2026 01:53:38 +0200
Subject: [PATCH] python3Packages.vcs-versioning: init at 1.1.1

---
 .../python-modules/vcs-versioning/default.nix | 60 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 62 insertions(+)
 create mode 100644 pkgs/development/python-modules/vcs-versioning/default.nix

diff --git a/pkgs/development/python-modules/vcs-versioning/default.nix b/pkgs/development/python-modules/vcs-versioning/default.nix
new file mode 100644
index 000000000000..096da5eac421
--- /dev/null
+++ b/pkgs/development/python-modules/vcs-versioning/default.nix
@@ -0,0 +1,60 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  packaging,
+  setuptools,
+  git,
+  pytestCheckHook,
+  vcs-versioning,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "vcs-versioning";
+  version = "1.1.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "pypa";
+    repo = "setuptools-scm";
+    tag = "vcs-versioning-v${finalAttrs.version}";
+    hash = "sha256-CfRzupWFtvmQLbubyr+eXRnLi4auZc2PA/Zz0aFNgaU=";
+  };
+
+  env.SETUPTOOLS_SCM_PRETEND_VERSION = finalAttrs.version;
+
+  postPatch = ''
+    pushd vcs-versioning
+  '';
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    packaging
+  ];
+
+  pythonImportsCheck = [
+    "vcs_versioning"
+  ];
+
+  doCheck = false; # infinite recursion with pytest
+
+  nativeCheckInputs = [
+    git
+    pytestCheckHook
+  ];
+
+  pytestFlags = [ "-vvv" ];
+
+  passthru.tests.pytest = vcs-versioning.overridePythonAttrs { doCheck = true; };
+
+  meta = {
+    changelog = "https://github.com/pypa/setuptools-scm/releases/tag/${finalAttrs.src.tag}";
+    description = "The blessed package to manage your versions by scm tags";
+    homepage = "https://github.com/pypa/setuptools-scm/tree/main/vcs-versioning";
+    license = lib.licenses.mit;
+    teams = [ lib.teams.python ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 126941497f48..0affe265a11a 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -21069,6 +21069,8 @@ self: super: with self; {
 
   vcrpy = callPackage ../development/python-modules/vcrpy { };
 
+  vcs-versioning = callPackage ../development/python-modules/vcs-versioning { };
+
   vcversioner = callPackage ../development/python-modules/vcversioner { };
 
   vdf = callPackage ../development/python-modules/vdf { };